//
// set colours
//
$if(%_isplaying%,
$puts(col_plno,FFFFFF|FFFFFF)
$puts(col_trno,7EBABE|FFFFFF)
$puts(col_length,0000FF|FFFFFF)
$puts(col_title,FFFFFF|FFFFFF)
$puts(col_light,FFFFFF|FFFFFF)
$puts(col_trans_light,FFFFFF|FFFFFF)
$puts(col_trans_dark,000000|000000)
$if($or(%singletrack%,%various%),
$puts(col_artist,FFFFFF|FFFFFF)
,
$puts(col_artist,55DD00|7EBABE)
)
,
$puts(col_plno,7EBABE|7EBABE)
$puts(col_trno,0055DD|7EBABE)
$puts(col_length,CCCCCC|FFFFFF)
$puts(col_title,CC9922|7EBABE)
$puts(col_light,808080|808080)
$puts(col_trans_light,808080|808080)
$puts(col_trans_dark,220000|220000)
$if($or(%singletrack%,%various%),
$puts(col_artist,99FF55|7EBABE)
,
$puts(col_artist,55DD00|7EBABE)
)
)
$puts(col_playing,FFFFFF|FFFFFF)
$puts(col_genre,996600|7EBABE)
$puts(col_date,996600|7EBABE)
$puts(col_album,CC9922|7EBABE)
$puts(col_dark,404040|000000)
$puts(col_disc,0080FF|0080FF)
$puts(col_bonus,808000|808000)
$puts(col_sep,7EBABE|7EBABE)
$puts(col_a_gain,505050|505050)
$puts(col_t_gain,808080|808080)
$puts(col_station,2299CC|FFFFFF)


//
// set variables
//
$puts(symb_playing,'>>>>>>')
$puts(symb_a_gain,'[A]')
$puts(symb_t_gain,'[T]')
$puts(text_plno,%_playlist_number%)
$puts(text_station,%station%' ')
$puts(text_bonus,*Bonus Track*)
$puts(text_album,%album%[ %volume%])
$puts(text_disc,[Disc %disc% ][''%discname%''])
$if(%date%,
$puts(text_date,%date%)
,
$puts(text_date,$char(9472)$char(9472)$char(9472)$char(9472))
)
$if(%various%,
$puts(text_artist,Various Artists)
,
$puts(text_artist,%artist%)
)
$puts(len_date,$len($get(text_date)))
$puts(len_station,$len($get(text_station)))
$puts(len_album,$len($get(text_album)))
$puts(len_disc,$len($get(text_disc)))
$puts(len_artist,$len($get(text_artist)))
$puts(len_divider_point,15)
$puts(len_min,32)
$puts(len_tag,$len($longest($longest($longest($get(text_artist),$get(text_album)),$get(text_disc)),%genre%)))
$if(%singletrack%,
$puts(space,$get(len_min))
,
$puts(space,$ifgreater($get(len_tag),$get(len_min),$get(len_tag),$get(len_min)))
)
$if(%various%,
$puts(len_divider,$sub(80,$add($len(%artist%),$add(3,$add($get(space),$len(%title%))))))
,
$puts(len_divider,$sub(80,$add($get(space),$len(%title%))))
)


//
// apply colours
//
$if(%date%,
$puts(text_date,$get(col_date)%date%)
,
$puts(text_date,$get(col_sep)$char(9472)$char(9472)$char(9472)$char(9472))
)
$puts(text_plno,$get(col_plno)$get(text_plno))
$puts(symb_playing,$transition($get(symb_playing),$get(col_trans_dark),$get(col_trans_light)))
$puts(text_single_artist,$repeat(' 
',$add($sub($get(space),$get(len_artist)),1))$get(col_artist)$get(text_artist)' ')
$puts(text_bonus,$get(col_bonus)$get(text_bonus))
$puts(text_album,$get(col_album)$get(text_album)$repeat(' ',$sub($get(space),$get(len_album))))
$puts(text_artist,$get(col_artist)$get(text_artist)$repeat(' ',$sub($get(space),$get(len_artist))))
$puts(text_disc,$get(col_disc)$get(text_disc)$repeat(' ',$sub($get(space),$get(len_disc))))
$puts(text_station,$get(col_station)$cut($get(text_station),$get(space))$repeat(' 
',$sub($get(space),$get(len_station))))
$puts(text_genre,$get(col_genre)%genre%$repeat(' ',$sub($get(space),$len(%genre%))))
$puts(text_date,$get(text_date)$transition($repeat($char(9472),$get(len_divider_point)),$get(col_sep),$get(col_trans_dark)
)$repeat(' ',$sub($sub($get(space),$get(len_date)),$get(len_divider_point))))
$puts(text_divider,$get(col_sep)$repeat($char(9472),$get(len_divider))$transition($repeat($char(9472),$get(len_divider_point)),$get(
col_sep),$get(col_trans_dark)))


//
// set playlist number formatting
//
$puts(plno,$get(col_sep)$char(9500)$get(text_plno)$get(col_sep)$char(9508))
$ifgreater(%_playlist_number%,999,
,$puts(plno,$get(col_sep)$char(9500)$get(col_dark)'0'$get(text_plno)$get(col_sep)$char(9508))
)
$ifgreater(%_playlist_number%,99,
,$puts(plno,$get(col_sep)$char(9500)$get(col_dark)'00'$get(text_plno)$get(col_sep)$char(9508))
)
$ifgreater(%_playlist_number%,9,
,$puts(plno,$get(col_sep)$char(9500)$get(col_dark)'000'$get(text_plno)$get(col_sep)$char(9508))
)


//
// set album/artist formatting
//
$if($strcmp($num(%tracknumber%,1),1),
$puts(album,$get(col_sep)$char(9484)$repeat($char(9472),$get(space))$char(9472))
)
$if($strcmp($num(%tracknumber%,1),2),
$puts(album,$get(col_sep)$char(9500)$get(text_artist)' ')
)
$if($strcmp($num(%tracknumber%,1),3),
$puts(album,$get(col_sep)$char(9500)$get(text_album)' ')
)
$if($strcmp($num(%tracknumber%,1),4),
$if($strcmp(0,$get(len_disc)),
$puts(album,$get(col_sep)$char(9500)$get(text_genre)' ')
,
$puts(album,$get(col_sep)$char(9500)$get(text_disc)' ')
)
)
$if($strcmp($num(%tracknumber%,1),5),
$if($strcmp(0,$get(len_disc)),
$puts(album,$get(col_sep)$char(9492)$get(text_date)' ')
,
$puts(album,$get(col_sep)$char(9500)$get(text_genre)' ')
)
)
$if($strcmp($num(%tracknumber%,1),6),
$if($strcmp(0,$get(len_disc)),
$puts(album,' '$repeat(' ',$get(space))' ')
,
$puts(album,$get(col_sep)$char(9492)$get(text_date)' ')
)
)
$ifgreater(%tracknumber%,6,
$puts(album,' '$repeat(' ',$get(space))' '),
)

// if no tracknumber
$if(%tracknumber%,,
$if(%station%,
$puts(album,$get(col_sep)-$get(text_station)' ')
,
$if(%artist%,
$puts(album,$get(col_sep)$get(text_artist)'  ')
,
$puts(album,$get(col_sep)%_filename%' ')
)
)
)

// if %singletrack%
$if(%singletrack%,
$puts(album,$get(text_single_artist))
)


//
// set tracknumber formatting
//
$ifgreater(%tracknumber%,9,
$puts(tracknumber,$get(col_trno)$num(%tracknumber%,2))
,
$puts(tracknumber,$get(col_dark)0$get(col_trno)$num(%tracknumber%,1))
)
$if($strcmp($num(%tracknumber%,1),1),
$puts(tracknumber,$get(col_sep)$char(9532)$get(tracknumber)$get(col_sep)$char(9532))
)
$ifgreater(%tracknumber%,1,
$if(%lasttrack%,
$puts(tracknumber,$get(col_sep)$char(9492)$get(tracknumber)$get(col_sep)$char(9484))
,
$puts(tracknumber,$get(col_sep)$char(9500)$get(tracknumber)$get(col_sep)$char(9474))
),
)
$if(%tracknumber%,,
$if(%artist%,
$puts(tracknumber,$get(col_sep) $char(9472)$char(9472) $get(col_sep))
,
$puts(tracknumber,)
)
)
$if($and(%singletrack%,%tracknumber%),
$puts(tracknumber,$get(col_sep) $char(9472)$char(9472) $get(col_sep))
)


//
// set title formatting
//
$if(%various%,
$puts(title,$get(col_artist)%artist%$get(col_dark)' - '$get(col_title)%title%$get(col_dark)[ %version%])
,
$puts(title,$get(col_title)%title%$get(col_dark)[ %version%])
)
$if(%bonustrack%,$puts(title,$get(title) $get(col_bonus)$get(text_bonus)))


//
// set divider
//
$if($and($strcmp($num(%tracknumber%,1),1),$not(%singletrack%)),
$puts(divider,$get(text_divider))
)


//
//set ReplayGain info
//
$puts(rpg,
$if(%__replaygain_track_gain%,
$if(%__replaygain_album_gain%,
$get(col_a_gain)$if(%__replaygain_album_gain%,
$get(symb_a_gain)),
$get(col_t_gain)$if(%__replaygain_track_gain%,$get(symb_t_gain))),
$puts(width_gain_symb,$len($longest($get(symb_a_gain),$get(symb_t_gain))))
$repeat(' ',$get(width_gain_symb))
))


//
// set length
//
$puts(length,$get(col_length)$pad_right(%_length%,5))


//
//set now playing symbol
//
$puts(playing,$get(col_playing)$if(%_isplaying%,$get(symb_playing)))


//
// set spacer tracknumber title
//
$if($strcmp($num(%tracknumber%,1),1),
$puts(spacer_trno_title,$get(col_sep)$char(9472))
,
$puts(spacer_trno_title,' ')
)
$if($and(%singletrack%,%tracknumber%),
$puts(spacer_trno_title,' ')
)


//
// remove underscore
//
$replace(


//
// create string
//
$get(plno)
' '
$get(album)
$get(tracknumber)
$get(spacer_trno_title)
$get(title)
$get(divider)
$char(9)
$get(playing)
$get(length)
$get(rpg)


//
// end remove underscore
//
,_, )